Re: Mail merge only fills first row of labels with data



Are you using a Tablet PC? If so there is an issue with the utility to
propagate the set up of the first label to the other labels on the sheet.

The following macro will overcome the problem with propagation of mail merge
field fields with a label type mail merge when using a Tablet PC and some
other Computers that have Tablet PC Functionality available:

Sub MailMergePropagateLabel()

Dim atable As Table

Dim i As Long, j As Long

Dim source As Cell, target As Cell

Dim myrange As Range

Set atable = ActiveDocument.Tables(1)

Set source = atable.Cell(1, 1)

Set myrange = source.Range

myrange.Collapse wdCollapseStart

ActiveDocument.Fields.Add Range:=myrange, Text:="NEXT", _

PreserveFormatting:=False

source.Range.Copy

For j = 2 To atable.Columns.Count

Set target = atable.Cell(1, j)

If target.Range.Fields.Count > 0 Then

target.Range.Paste

End If

Next j

For i = 2 To atable.Rows.Count

For j = 1 To atable.Columns.Count

Set target = atable.Cell(i, j)

If target.Range.Fields.Count > 0 Then

target.Range.Paste

End If

Next j

Next i

atable.Cell(1, 1).Range.Fields(1).Delete

End Sub



It is suggested that you put this code into a template that you save in the
Word Startup folder so that it becomes an add-in and will be available
whenever you need it. As the macro has the same name as the Word Command
that is supposed to do the job, this macro will run when the Update Labels
button is used when setting up the mail merge label main document.


--
Hope this helps.

Please reply to the newsgroup unless you wish to avail yourself of my
services on a paid consulting basis.

Doug Robbins - Word MVP, originally posted via msnews.microsoft.com

"Cindy" <Cindy@xxxxxxxxxxxxxxxxxxxxxxxxx> wrote in message
news:A4B19387-9284-448D-A10B-FF7FAB7919F8@xxxxxxxxxxxxxxxx
When trying to complete labels mail merge with excel document, it only
fills
in the first row of the labels. It doesn't complete the whole sheet of
labels (I have 20 addresses on my excel document and only 3 show up).
What
am I doing wrong?


.