Re: how to shutdown computer?

• From: "Torgeir Bakken \(MVP\)" <Torgeir.Bakken-spam@xxxxxxxxx>
• Date: Thu, 26 May 2005 18:44:37 +0200

James Pang wrote:

the dos command does not give user a option
so is that possible give out a msg box if user do not click no
in 30 second then turn off computer?

Hi,

With a VBScript (.vbs file):

'--------------------8<----------------------

Set oShell = CreateObject("WScript.Shell")

iBtnCode = oShell.Popup("Turn off the computer?", 30, "Shutting down", 4 + 32)

If iBtnCode <> 7 Then
  ShutDown ".", "PowerOff"
End If

Sub ShutDown(sNode, sAction)

' First parameter:
' use "." for local computer

' Second parameter:
' Use "PowerOff" for a poweroff
' Use "PowerOff_Force" for a forced poweroff
' Use "Shutdown" for a shutdown
' Use "Shutdown_Force" for a forced shutdown
' Use "Reboot" for a reboot
' Use "Reboot_Force" for a forced reboot
' Use "LogOff" for a logoff
' Use "LogOff_Force" for a forced logoff

  Const EWX_LOGOFF = 0
  Const EWX_SHUTDOWN = 1
  Const EWX_REBOOT = 2
  Const EWX_FORCE = 4
  Const EWX_POWEROFF = 8

  On Error Resume Next
  Set oWMI = GetObject("winmgmts:" _
     & "{impersonationLevel=impersonate,(Shutdown)}!\\" _
     & sNode & "\root\cimv2")

  Set colOperatingSystems = oWMI.ExecQuery _
     ("Select * from Win32_OperatingSystem")
  For Each obj in colOperatingSystems
    Set oOS = obj :  Exit For
  Next
  If Err.Number <> 0 Then
    WScript.Echo "Could not connect to " & sNode
    Exit Sub
  End If

  sAction = LCase(sAction)

  Select Case sAction
    Case "logoff"
      iCmd = EWX_LOGOFF
    Case "logoff_force"
      iCmd = EWX_LOGOFF + EWX_FORCE
    Case "shutdown"
      iCmd = EWX_SHUTDOWN
    Case "shutdown_force"
      iCmd = EWX_SHUTDOWN + EWX_FORCE
    Case "reboot"
      iCmd = EWX_REBOOT
    Case "reboot_force"
      iCmd = EWX_REBOOT + EWX_FORCE
    Case "poweroff"
      iCmd = EWX_POWEROFF
    Case "poweroff_force"
      iCmd = EWX_POWEROFF + EWX_FORCE
    Case Else
       MsgBox "Error: invalid input parameter!", _
           vbExclamation + vbSystemModal, "ShutDown"
  End Select

  oOS.Win32shutdown iCmd

End Sub
'--------------------8<----------------------

WSH 5.6 documentation (local help file) can be downloaded from here
if you haven't got it already:
http://msdn.microsoft.com/downloads/list/webdev.asp

--
torgeir, Microsoft MVP Scripting and WMI, Porsgrunn Norway
Administration scripting examples and an ONLINE version of
the 1328 page Scripting Guide:
http://www.microsoft.com/technet/scriptcenter/default.mspx
.

• References:
  • how to shutdown computer?
    • From: James Pang

• Prev by Date: Re: List Date a user was disabled
• Next by Date: Registry Data Appending NOT Overwriting
• Previous by thread: Re: how to shutdown computer?
• Next by thread: usb disable
• Index(es):
  • Date
  • Thread

• Windows
• Science
• Usenet

• Archive
• About
• Privacy
• Search
• Imprint