Re: CDBL Function truncates decimals

I have an international app translated into many languages. My problem is
that the Val Function truncates my data and this is how it seems.

strNumber = "2,5" (I know its a string but its because I'm using the
Spanish
numbering system). I would like it to return the US format 2.5 and it
currently returns 2

Public Function ConvertNumberforSQL (ByVal sValue As String, Optional
ByVal
vlDefaultNumber As Double= 0) as Double

If sValue = "" Or IsNull(sValue) Then
ConvertNumberforSQL = vlDefaultNumber
ElseIf Not IsNumeric(sValue) Then
ConvertNumberforSQL = vlDefaultNumber
Else
ConvertNumberforSQL = Val(sValue)
End If
End Function

I have my locale settings set as Spainis(Spain) and their numbering
system
obviously is different than the US. However I need the data 2,5 to be
formatted into US English (2.5) so that I can use the value in the
following
SQL string.

INSERT INTO TableName VALUES(sValue)

Since the Spanish formatting has a comma, the SQL statement seems to have
2
fields in stead of one. Which of course casues an error.

I tried the CDBL(sValue) but it also returns a value of 2.

Any hepl here would be greatly apprciated

Assuming this function will always be used on a numerical argument where the
decimal point is a comma, you can use the Replace function to change the
comma to a dot before proceeding. Here is a modification to your function
that does that...

Public Function ConvertNumberforSQL(ByVal sValue As String, _
Optional ByVal vlDefaultNumber As Double = 0) As Double
' Usually places that use the comma for their decimal point
' use a dot for their thousands separator. Just in case
' you number came in with dots, let's get rid of them first
sValue = Replace$(sValue, ".", "")
' Now, change the comma, if any, into a dot.
sValue = Replace$(sValue, ",", ".")
If sValue = "" Or IsNull(sValue) Then
ConvertNumberforSQL = vlDefaultNumber
ElseIf Not IsNumeric(sValue) Then
ConvertNumberforSQL = vlDefaultNumber
Else
ConvertNumberforSQL = Val(sValue)
End If
End Function

However, I see that you are using the IsNumeric function within your own
function. You may wish to eliminate that dependency and use one of the
functions I provide in the IsNumeric caution I have included below (be sure
to read the Note included in it as I think it applies to you). By the way,
since the IsNumber function I provide as an alternative already checks for
"" and vbNullString, you should be able to change your If-Then testing into
this instead (assuming you decide to use it)...

If Not Value Like "*[!0-9.]*" And Not Value Like "*.*.*" And _
Len(Value) > 0 And Value <> "." And Value <> vbNullString Then
ConvertNumberforSQL = Val(sValue)
Else
ConvertNumberforSQL = vlDefaultNumber
End If

Now, from a previous post of mine...

I usually try and steer people away from using IsNumeric to "proof"
supposedly numeric text. Consider this (also see note below):

ReturnValue = IsNumeric("($1,23,,3.4,,,5,,E67$)")

Most people would not expect THAT to return True. IsNumeric has some "flaws"
in what it considers a proper number and what most programmers are looking
for.

I had a short tip published by Pinnacle Publishing in their Visual Basic
Developer magazine that covered some of these flaws. Originally, the tip was
free to view but is now viewable only by subscribers.. Basically, it said
that IsNumeric returned True for things like -- currency symbols being
located in front or in back of the number as shown in my example (also
applies to plus, minus and blanks too); numbers surrounded by parentheses as
shown in my example (some people use these to mark negative numbers);
numbers containing any number of commas before a decimal point as shown in
my example; numbers in scientific notation (a number followed by an upper or
lower case "D" or "E", followed by a number equal to or less than 305 -- the
maximum power of 10 in VB); and Octal/Hexadecimal numbers (&H for
Hexadecimal, &O or just & in front of the number for Octal).

NOTE:
======
In the above example and in the referenced tip, I refer to $ signs and
commas and dots -- these were meant to refer to your currency, thousands
separator and decimal point symbols as defined in your local settings --
substitute your local regional symbols for these if appropriate.

As for your question about checking numbers, here are two functions that I
have posted in the past for similar questions..... one is for digits only
and the other is for "regular" numbers:

Function IsDigitsOnly(Value As String) As Boolean
IsDigitsOnly = Len(Value) > 0 And _
Not Value Like "*[!0-9]*"
End Function

Function IsNumber(ByVal Value As String) As Boolean
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9.]*" And _
Not Value Like "*.*.*" And _
Len(Value) > 0 And Value <> "." And _
Value <> vbNullString
End Function

Here are revisions to the above functions that deal with the local settings
for decimal points (and thousand's separators) that are different than used
in the US (this code works in the US too, of course).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP And _
Value <> vbNullString
End Function

I'm not as concerned by the rejection of entries that include one or more
thousand's separators, but we can handle this if we don't insist on the
thousand's separator being located in the correct positions (in other words,
we'll allow the user to include them for their own purposes... we'll just
tolerate their presence).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
Dim TS As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Get local setting for thousand's separator
' and eliminate them. Remove the next two lines
' if you don't want your users being able to
' type in the thousands separator at all.
TS = Mid$(Format$(1000, "#,###"), 2, 1)
Value = Replace$(Value, TS, "")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP And _
Value <> vbNullString
End Function


Rick


.

Relevant Pages

  • Re: CDBL Function truncates decimals
    ... Is there a way to format a number into US ... Public Function ConvertNumberforSQL (ByVal sValue As String, ... Since the Spanish formatting has a comma, the SQL statement seems to have ...
    (microsoft.public.vb.general.discussion)
  • Re: CDBL Function truncates decimals
    ... Public Function ConvertNumberforSQL (ByVal sValue As String, ... Since the Spanish formatting has a comma, the SQL statement seems to have ...
    (microsoft.public.vb.general.discussion)
  • Re: CDBL Function truncates decimals
    ... Optional ByVal vlDefaultNumber As Double = 0) As ... ' Now, change the comma, if any, into a dot. ... ConvertNumberforSQL = vlDefaultNumber ...
    (microsoft.public.vb.general.discussion)
  • Re: CDBL Function truncates decimals
    ... Optional ByVal vlDefaultNumber As Double = 0) As ... ' Now, change the comma, if any, into a dot. ... ConvertNumberforSQL = vlDefaultNumber ...
    (microsoft.public.vb.general.discussion)
  • Re: CDBL Function truncates decimals
    ... Public Function ConvertNumberforSQL (ByVal sValue As String, ... ByVal vlDefaultNumber As Double= 0) as Double ... Since the Spanish formatting has a comma, the SQL statement seems to ...
    (microsoft.public.vb.general.discussion)