Re: What am I doing wrong?

Tech-Archive recommends: Repair Windows Errors & Optimize Windows Performance


"AK" <nospam@xxxxxxxxxxx> wrote

My pea brain is thus thinking that object itself must have a "handle" ....
which is NOT the Name Property the object. While the name of the object is
itself an object (along the lines like this thead is a discussion object) it
is NOT the object itself (french frys mentioned earlier). Heck, maybe that
"handle" as I call it, is indeed the Name of the object, which, howevver,
is different than the Name Property.

Not quite, as Rick states, the Name is a convenience for the programer,
the OS is going to use a window's handle to differentiate between objects.
Some of those objects may in fact have the same Name, but their handle
will be unique. For example, in a new project, add this to Form1:

Private Sub Form_Load()

Caption = Me.Name & " - " & CStr(Me.hWnd)
Me.Move Forms.Count * 1000, Forms.Count * 1000

If Forms.Count < 4 Then
With New Form1
.Show
End With
End If

End Sub

When you run the program you'll see 4 forms showing, all with the
name of "Form1", but each with a unique windows handle. (Of
course the computer reduces everything down to a numeric value
to store anything in memory, so the handle is actually a number)

Windowed controls also have a handle (the hWnd property). While
you can pass that handle value around to various routines, it will require
a little API trickery to put it to use.

So, in a nutshell, you can't (easily) use a value to represent an object.
You can (more easily) use a reference to some object instead.

Anytime you are assigning objects to variables, expect to use Set!

With Text1 added to a new form, try this code in the form:

Private Sub Form_Load()
Dim ref1 As TextBox
Dim ref2 As Control
Dim ref3 As Object
Dim ref4 As Variant

Set ref1 = Text1
Set ref2 = Text1
Set ref3 = Text1
Set ref4 = Text1

ref1.Text = "Some text string"
ref2.Move 90, 90
ref3.BackColor = vbBlack
ref4.ForeColor = vbWhite

End Sub


What that shows is that you can have any number of references
all pointing to the same object, and there are a few different VB
data types that accept being assigned an object. I listed the
Dim statements in order from the specific to the more general
form of reference. Only ref1 will have Intellisense, the others
do not know what type of object they might be assigned and
therefore cannot know what properties and methods to show
for the dropdown list in the IDE.

You don't have to specifically create a variable reference to
pass objects around, you can pass the objects themselves,
where the Sub or Function will use a reference as one of it
parameters:

Private Sub SelectAllText(TextBox As TextBox)
With TextBox
.SelStart = 0
.SelLength = Len(.Text)
End With
End Sub

That can be called passing in any textbox object:

SelectAllText Text1
SelectAllText Text2
' ... etc...

The point here is that when you want to work with objects in
a generic fashion (such as the above sub) work with them as
objects, and not as values (either the Name or hWnd or other
such value.) Also keep it clear in your mind that objects are
not values, objects have properties that are set to some value
or another. When you have a variable that contains data,
such as a string or number, then it is a 'variable that contains
a value'. When you have variables that refer to objects, then
you have a 'variable that is a reference to an object'.

The main difference is that when you erase a value (or assign
a new value), the old value is gone. When you erase a
reference (by setting the variable to Nothing, or assigning
a new object) the actual object will only be destroyed if that
is the last remaining reference to that object. In other words,
while ref1 can be set to Nothing in the above example, the
actual textbox will not be destroyed, there are other references
to that object remaining; such as the other refX variables plus
one in the Controls collection, and the generic one used by VB.
(The one called 'Text1' or other such name you give it.)

And just to reiterate, because it is important:

Anytime you are assigning objects to variables, expect to use Set!

A = B ' is a value assignment
Set A = B ' is a reference assignment

HTH
LFS











.

Relevant Pages

  • RXParse module v.91 (by robic0)
    ... # Unicode character reference ... sub original_content ... then call content handler with $content ...
    (comp.lang.perl.misc)
  • RE: Using excel to Determine if a File Exists in SharePoint
    ... Microsoft Scripting Runtime ... Is there a reference I need to add? ... Sub CheckIfexists() ... You just need to know your local sharepoint ...
    (microsoft.public.excel.programming)
  • Re: Emailing a Report
    ... make sure you have a reference to a Microsoft DAO Library ... The Sub LoopAgmtsSendEmail is highlighted by the Debugger. ... 'pSQL -- defines the recordset to open ... You must remember to enclose literal values in quotes and concatenate them; the final string must have commas too, ...
    (microsoft.public.access.modulesdaovba)
  • Re: Shared Method Problem With "Global" Storage
    ... a routine in Module1 which then calls code back in Form1 ... ButtonHasBeenClicked but the reference to ButtonHasBeenClicked ... instance member of a class from within a shared method or shared ... In a shared Sub, you can not access an instance field withouth ...
    (microsoft.public.dotnet.languages.vb)
  • Re: Please help me clarify these byVal vs. byRef subtleties
    ... ByVal & ByRef Parameters are independent of Reference & Value Types. ... > I've got a class, DataHider, with one private string field (i.e., ... > Public Sub callObjectMethodPassedByVal(ByVal myObj As ...
    (microsoft.public.dotnet.languages.vb)