Re: Resend of- 7/15 ->2004: How zoom+ view of received small-font html newsletters?

From: Mickey Stevens (mickey.stevens_at_mvps.org)
Date: 07/28/04 

Date: Tue, 27 Jul 2004 21:04:30 -0500

Not with complex HTML, which is what I suspect you're referring to. Here's
a workaround if you're interested:

Copy this script from a message from Allen Watson:

property browser : ""

if browser = "" then
    set browser to choose file of type "APPL" with prompt "Please select
your default browser."
end if
tell application "Finder" to set defBrowserName to name of browser

tell application "Microsoft Entourage"
    set theMsg to item 1 of (get current messages)
    try
        if has html of theMsg is true then
            set pts to item 1 of (get parts of theMsg)
            set pts to parts of pts
            repeat with i from 1 to (count pts)
                set aPart to item i of pts
                set theType to type of aPart
                set theSubtype to subtype of aPart
                if theType is "text" and theSubtype is "html" then
                    set theHTML to content of aPart
                    exit repeat
                end if
            end repeat
            set tempfile to open for access "tempHTML2.html" with write
permission
            write theHTML to tempfile
            close access tempfile
            set theFile to "tempHTML2.html"
        else
            display dialog "Selected message seems to have no HTML to open."
            return
        end if
    on error theErr
        display dialog theErr
        return
    end try
end tell
set theDisk to path to startup disk as string
set theFile to theDisk & theFile
-- Give the file the creator type of the default browser
tell application "Finder"
    set f to alias theFile
    set ct to creator type of browser
    set ft to "TEXT"
    set creator type of f to ct
    set file type of f to ft
end tell
try
    set thePath to POSIX path of theFile
    set theDisk to text 1 thru -2 of theDisk -- remove delimiter
    set theURL to "file://" & theDisk & thePath
    tell application defBrowserName
        activate
        open location (theURL)
    end tell
on error theErr
    display dialog theErr
end try
delay 5
tell application "Finder" to delete theFile
tell application "Finder" to empty trash

Copy everything starting with "tell" and ending with "trash" and paste it
into a blank script in Script Editor (/Applications/AppleScript/Script
Editor/). Then, save it to the "Entourage Script Menu Items" folder in the
Microsoft User Data folder. I called it "Open HTML in Browser". Then, when
you're viewing a newsletter, click the Script menu (to the right of the Help
menu), and select the "Open HTML in Browser" script. You'll be prompted to
select a browser. Once you choose one, the newsletter will open in the
browser, which will allow you to increase or decrease font size (process
varies depending on browser; for Internet Explorer and Safari, the command
is in the View menu, or on the toolbar if you've customized it).

On 7/27/04 7:57 PM, in article
BD2C4814.3066%nnager@vnoxsxpxaxmv.fullerton.edu, "Norman R. Nager, Ph.D."
<nnager@vnoxsxpxaxmv.fullerton.edu> wrote:

> In Entourage Email 2004, is there any way to change the view of incoming
> html newsletters so that the text font appears larger (and still retain the
> ability to click on links)?
>
> Respectfully, Norm
> 

-- 
Mickey Stevens (Microsoft MVP for Office:mac)
PowerPoint FAQ featuring PowerPoint:mac: <http://www.pptfaq.com/>
Entourage Help Page: <http://www.entourage.mvps.org/>

Relevant Pages