Re: txt.Datei als Array einlesen ??

Tech Tip: Click here to run a free scan for Windows Errors and optimize PC performance

Hallo Markus,

Löw" <markusloew atnospam web.de> schrieb:
> Parameter sollen in einer txt.Datei hinterlegt werden in folgender
> Form
> Verzeichnis1=c:\
> mailTo=ja
> An=mail@xxxxxxx
> Betrifft: Tagesmeldung
> Diese Parameter sollen nun ausgelesen werden und im VBA-Code
> weiterverarbeitet werden.
> Nur wie kann ich die Daten aus der txt.Datei auslesen?
> Super wäre, wenn es möglich wäre, anhand der Daten links von den
> Gleichheitszeichen zu erkennen, um was es sich handelt, um zum
> Beispiel auch mal ein CC oder BCC anzugeben, ohne hier Platzhalter
> in der TxT einzugeben

entweder, wie von Ulrich vorgeschlagen, Open, Get, Line Input verwenden,
oder gleich eine Ini-Datei benutzen.


Option Explicit
Private Declare Function GetPrivateProfileString _
Lib "kernel32" Alias "GetPrivateProfileStringA" ( _
ByVal lpApplicationName As String, _
ByVal lpKeyName As String, _
ByVal lpDefault As String, _
ByVal lpReturnedString As String, _
ByVal nSize As Long, _
ByVal lpFileName As String _
) As Long

Private Declare Function WritePrivateProfileString _
Lib "kernel32" Alias "WritePrivateProfileStringA" ( _
ByVal AppName As String, _
ByVal KeyName As String, _
ByVal keydefault As String, _
ByVal FileName As String _
) As Long
' Funktion, um Einträge in .ini Datei schreiben

Private Const Einstellungen = "c:\MeineEinstellungen.ini"
' Name der .ini Datei (wenn sie nicht existiert, wird sie angelegt)

Sub EinstellungenSpeichern()

WritePrivateProfileString "Sektion 1", "Verzeichnis", _
"C:\", Einstellungen
WritePrivateProfileString "Sektion 1", "mailTo", _
"An", Einstellungen
WritePrivateProfileString "Sektion 1", "An", _
"mail@xxxxxxx", Einstellungen
WritePrivateProfileString "Sektion 1", "Betrifft", _
"Tagesmeldung", Einstellungen

End Sub

Sub EinstellungenLaden()
Dim strInhalt As String
strInhalt = String(1000, 0)
GetPrivateProfileString "Sektion 1", "Verzeichnis", _
"Nicht vorhanden", strInhalt, Len(strInhalt), Einstellungen
MsgBox Left$(strInhalt, InStr(1, strInhalt, Chr(0)) - 1), _
, "Verzeichnis"
strInhalt = String(1000, 0)
GetPrivateProfileString "Sektion 1", "mailTo", _
"Nicht vorhanden", strInhalt, Len(strInhalt), Einstellungen
MsgBox Left$(strInhalt, InStr(1, strInhalt, Chr(0)) - 1), _
, "mailTo"
strInhalt = String(1000, 0)
GetPrivateProfileString "Sektion 1", "An", _
"Nicht vorhanden", strInhalt, Len(strInhalt), Einstellungen
MsgBox Left$(strInhalt, InStr(1, strInhalt, Chr(0)) - 1), _
, "An"
GetPrivateProfileString "Sektion 1", "Betrifft", _
"Nicht vorhanden", strInhalt, Len(strInhalt), Einstellungen
MsgBox Left$(strInhalt, InStr(1, strInhalt, Chr(0)) - 1), _
, "Betrifft"
End Sub

Sub EinenEintragEntfernen()
WritePrivateProfileString "Sektion 1", "Verzeichnis", _
vbNullString, Einstellungen
End Sub

Sub SektionEntfernen()
WritePrivateProfileString "Sektion 1", vbNullString, _
vbNullString, Einstellungen
End Sub

Folgendermaßen würde die Inidatei aussehen (Mit Notepad geöffnet):

[Sektion 1]
Verzeichnis=C:\
mailTo=An
An=mail@xxxxxxx
Betrifft=Tagesmeldung

Das ist natürlich erweiterbar, du kannst neue Sektionen anlegen und für
jede Sektion neue Einträge hinzufügen.



MfG
Michael

--
Michael Schwimmer
Home : http://michael-schwimmer.de
Excel VBA ISBN 3-8273-2183-2
.

Relevant Pages