Re: Termin in Textdatei
- From: Peter Götz <gssg_nospam@xxxxxxxxxxx>
- Date: Mon, 13 Mar 2006 10:55:21 +0100
Hallo "arepe",
"arepe" <arbepe@xxxxxxxx> schrieb im Newsbeitrag >news:1142238828.191676.5570@xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
Wir stellen uns hier üblicherweise mit unserem vollen Namen (Vor- u. Zuname)
vor.
Wäre schön, wenn Du Dich dieser Gepflogenheit anschliessen würdest.
Hai,
Was für'n Hai?
Weisser Hai?
mein Problem ist, ich habe ein Formular erstellt indem ein
Termin eingegeben wird, nun sollen einige Daten aus dem
Formular auch noch als Textdatei auf einem server abgelegt
werden! Kann mir jemand helfen, wie ich diese Textdatei
bekomme und sie gleich auf dem Server speicher?
Mit freundlichen Grüssen
Kleines Beispiel:
1 Form: Form1
mit 1 Steuerelementefeld bestehend aus
1 TextBox: txtInp(0)
1 TextBox: txtInp(1)
1 TextBox: txtInp(2)
1 CommandButton: cmdSave
' /// Code in Form1
Option Explicit
Private mFileName As String
Private Sub Form_Load()
mFileName = "\\Servername\Freigabe\TestDatei.txt"
txtInp(0).Text = "Termin"
txtInp(1).Text = "Bemerkung 1"
txtInp(2).Text = "Bemerkung 2"
cmdSave.Caption = "Speichern"
End Sub
Private Sub cmdSave_Click()
Dim Ret As Integer
Dim strBuffer As String
Ret = DataOk
Select Case Ret
Case -1
SaveData
ClearFields
Exit Sub
Case 0
strBuffer = "Feld Termin enthält kein gültiges Datum!"
Case 1 To 2
strBuffer = "Felder Bemerkung1 und Bemerkung2" & _
vbCrLf & "dürfen nicht leer sein!"
End Select
MsgBox strBuffer, vbExclamation
txtInp(Ret).SetFocus
End Sub
Private Sub ClearFields()
Dim i As Integer
For i = 0 To txtInp.UBound
txtInp(i).Text = ""
Next i
txtInp(0).SetFocus
End Sub
Private Function DataOk() As Integer
' Eingabedaten überprüfen
Dim Ret As Integer
Ret = -1
Select Case False
Case IsDate(txtInp(0).Text)
Ret = 0
Case Len(txtInp(1).Text) > 0
Ret = 1
Case Len(txtInp(2).Text) > 0
Ret = 2
End Select
DataOk = Ret
End Function
Private Sub SaveData()
Const DFmt As String = "dd.mm.yyyy hh:nn"
Dim FNum As Integer
Dim strBuffer As String
strBuffer = Format$(CDate(txtInp(0).Text), DFmt) & _
"; " & txtInp(1).Text & "; " & txtInp(2).Text
FNum = FreeFile
Open mFileName For Append As #FNum
Print #FNum, strBuffer
Close #FNum
End Sub
Private Sub txtInp_GotFocus(Index As Integer)
With txtInp(Index)
.SelStart = 0
.SelLength = Len(.Text)
End With
End Sub
' \\\ E N T E
Im Code der Form_Load-Ereignisprozedur musst Du den Pfad zu Deiner Textdatei
(mFileName) entsprechend Deiner Umgebung anpassen.
Programm starten und in die erste Textbox einen gültigen Datumsausdruck
eintragen.
In die beiden übrigen Textboxen ebenfalls irgendwelchen Text eintragen.
Auf Button "Speichern" klicken.
Die Function DataOK() wird aufgerufen, welche die Eingaben in den Textboxen
überprüft. Ist das Ergebnis der Überprüfung OK, gibt die Funktion DataOK()
den Wert -1 zurück. Wurde bei der Überprüfung ein fehlerhaft ausgefülltes
Feld gefunden, gibt DataOK() den Index dieses Feldes zurück.
Abhängig vom Rückgabewert der Function DataOK() wird bei -1 die
Speicherprozedur Sub Save() aufgerufen oder es wird bei Rückgabewerten 0...2
eine Meldung an den Benutzer (MsgBox) ausgegeben und anschliessend der Focus
auf das fehlerhaft ausgefüllte Feld gesetzt.
Gruß aus St.Georgen
Peter Götz
www.gssg.de (mit VB-Tips u. Beispielprogrammen)
.
- Follow-Ups:
- Re: Termin in Textdatei
- From: arepe
- Re: Termin in Textdatei
- References:
- Termin in Textdatei
- From: arepe
- Termin in Textdatei
- Prev by Date: Termin in Textdatei
- Next by Date: Scrollen geht nicht
- Previous by thread: Termin in Textdatei
- Next by thread: Re: Termin in Textdatei
- Index(es):
Relevant Pages
|
