Re: printing a logo

From: Gerben Kessen (gerben.kessen(_at_)wantit.nl)
Date: 06/01/04 

Date: Tue, 1 Jun 2004 10:10:16 +0200

Hai Roy,

There are a few ways to store a picture in a foxpro database, normaly a
general field is used for that pupose.
(Store the picture with APPEND GENERAL mygenfield FROM C:\WANTIT.BMP)
Use an "ole container" to display/print it in a form / report.

But there are a few downsites of a picture in a general field which depends
on the software installed on the client machine. So an other way is to store
it in a binary memo field.

See this sample code:

CREATE CURSOR GENDBF (FileName c(150), MemBin M NOCPTRANS)
INSERT INTO GENDBF VALUES ;
("levejane.bmp", FILETOSTR(HOME() +
"Samples\Tastrade\Bitmaps\levejane.bmp"))
INSERT INTO GENDBF VALUES ;
("pattcaro.bmp", FILETOSTR(HOME() +
"Samples\Tastrade\Bitmaps\pattcaro.bmp"))
INSERT INTO GENDBF VALUES ;
("peacmarg.bmp", FILETOSTR(HOME() +
"Samples\Tastrade\Bitmaps\peacmarg.bmp"))
INSERT INTO GENDBF VALUES ;
("perelaur.bmp", FILETOSTR(HOME() +
"Samples\Tastrade\Bitmaps\perelaur.bmp"))
INSERT INTO GENDBF VALUES ;
("smittim.bmp", FILETOSTR(HOME() +
"Samples\Tastrade\Bitmaps\smittim.bmp"))
GO TOP

PUBLIC oform1

oform1=NEWOBJECT("form1")
oform1.SHOW
RETURN

**************************************************
DEFINE CLASS form1 AS FORM
TOP = 71
LEFT = 48
HEIGHT = 310
WIDTH = 504
CAPTION = "Fox Image Demo"
NAME = "Form1"

ADD OBJECT image1 AS IMAGE WITH ;
HEIGHT = 296, ;
LEFT = 3, ;
TOP = 8, ;
WIDTH = 381, ;
NAME = "Image1"

ADD OBJECT cmdPrevious AS COMMANDBUTTON WITH ;
TOP = 27, ;
LEFT = 422, ;
HEIGHT = 27, ;
WIDTH = 24, ;
CAPTION = "<", ;
NAME = "cmdPrevious"

ADD OBJECT cmdNext AS COMMANDBUTTON WITH ;
TOP = 27, ;
LEFT = 446, ;
HEIGHT = 27, ;
WIDTH = 24, ;
CAPTION = ">", ;
NAME = "cmdNext"

ADD OBJECT cmdQuit AS COMMANDBUTTON WITH ;
TOP = 72, ;
LEFT = 405, ;
HEIGHT = 27, ;
WIDTH = 84, ;
CAPTION = "Quit", ;
NAME = "cmdQuit"

PROCEDURE getimage
LPARAMETERS lpFileName, lpMemoBinFld

LOCAL lcTemp AS STRING
lcTemp = ADDBS(SYS(2023)) + "JPGTEMP\"
IF !DIRECTORY(lcTemp)
MD (lcTemp)
ENDIF
SET SAFETY OFF
STRTOFILE(lpMemoBinFld, lcTemp + lpFileName)
SET SAFETY ON
RETURN lcTemp + lpFileName
ENDPROC

PROCEDURE DESTROY
USE IN SELECT("GENDBF ")
SET SAFETY off
ERASE ADDBS(SYS(2023)) + "JPGTEMP\*.*"
RD ADDBS(SYS(2023)) + "JPGTEMP"
SET SAFETY on
ENDPROC

PROCEDURE LOAD
CD JUSTPATH(SUBSTR(SYS(16),AT(' ',SYS(16),2)))
ENDPROC

PROCEDURE INIT
THISFORM.image1.PICTURE = ;
THIS.getimage(GENDBF.FileName, GENDBF.MemBin)
ENDPROC

PROCEDURE cmdPrevious.CLICK
IF RECNO() <> 1
SKIP -1
THISFORM.image1.PICTURE = ;
THISFORM.getimage(GENDBF.FileName, GENDBF.MemBin)
THISFORM.REFRESH
ENDIF
ENDPROC

PROCEDURE cmdNext.CLICK
IF RECCOUNT() <> RECNO() AND !EOF()
SKIP
THISFORM.image1.PICTURE = ;
THISFORM.getimage(GENDBF.FileName, GENDBF.MemBin)
THISFORM.REFRESH
ENDIF
ENDPROC

PROCEDURE cmdQuit.CLICK
THISFORM.RELEASE
ENDPROC
ENDDEFINE

HTH,
Gerben Kessen.

"Roy Gourgi" <royng@videotron.ca> wrote in message
news:G0Wuc.105362$Ca5.1256568@wagner.videotron.net...
> Hi,
>
> I was wandering if there is anyway for me to store a picture (logo) and
then
> print it out in foxpro? What kind of field would I use and how would I be
> able to print it.
>
> Thanks in advance
> Roy
>
>