Re: Required Field for 7 Numeric digits only

IsNumeric is not a very good "number proofer" given what most programmers expect it to do. Perhaps you will find the following which I have posted in the past to the compiled VB newsgroups (but which applies equally to the VBA world as well)...

I usually try and steer people away from using IsNumeric to "proof" supposedly numeric text. Consider this (also see note below):

ReturnValue = IsNumeric("($1,23,,3.4,,,5,,E67$)")

Most people would not expect THAT to return True. IsNumeric has some "flaws" in what it considers a proper number and what most programmers are looking for.

I had a short tip published by Pinnacle Publishing in their Visual Basic Developer magazine that covered some of these flaws. Originally, the tip was free to view but is now viewable only by subscribers.. Basically, it said that IsNumeric returned True for things like -- currency symbols being located in front or in back of the number as shown in my example (also applies to plus, minus and blanks too); numbers surrounded by parentheses as shown in my example (some people use these to mark negative numbers); numbers containing any number of commas before a decimal point as shown in my example; numbers in scientific notation (a number followed by an upper or lower case "D" or "E", followed by a number equal to or less than 305 -- the maximum power of 10 in VB); and Octal/Hexadecimal numbers (&H for Hexadecimal, &O or just & in front of the number for Octal).

NOTE:
======
In the above example and in the referenced tip, I refer to $ signs and commas and dots -- these were meant to refer to your currency, thousands separator and decimal point symbols as defined in your local settings -- substitute your local regional symbols for these if appropriate.

As for your question about checking numbers, here are two functions that I have posted in the past for similar questions..... one is for digits only and the other is for "regular" numbers:

Function IsDigitsOnly(Value As String) As Boolean
IsDigitsOnly = Len(Value) > 0 And _
Not Value Like "*[!0-9]*"
End Function

Function IsNumber(ByVal Value As String) As Boolean
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9.]*" And _
Not Value Like "*.*.*" And _
Len(Value) > 0 And Value <> "." And _
Value <> vbNullString
End Function

Here are revisions to the above functions that deal with the local settings for decimal points (and thousand's separators) that are different than used in the US (this code works in the US too, of course).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP And _
Value <> vbNullString
End Function

I'm not as concerned by the rejection of entries that include one or more thousand's separators, but we can handle this if we don't insist on the thousand's separator being located in the correct positions (in other words, we'll allow the user to include them for their own purposes... we'll just tolerate their presence).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
Dim TS As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Get local setting for thousand's separator
' and eliminate them. Remove the next two lines
' if you don't want your users being able to
' type in the thousands separator at all.
TS = Mid$(Format$(1000, "#,###"), 2, 1)
Value = Replace$(Value, TS, "")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP And _
Value <> vbNullString
End Function

Rick





"LRay67" <LRay67@xxxxxxxxxxxxxxxxxxxxxxxxx> wrote in message news:7B664E67-89AE-49B9-BA39-81285BC04B86@xxxxxxxxxxxxxxxx
Rick, you are correct...played with a couple of the scenarios you gave...and
dang.....have to play some more on the code. Thanks for the catch

There has to be an easier way of doing this......

"Rick Rothstein (MVP - VB)" wrote:

That code will accept all of the following as being 7 digits...

1234.56 1,,,,,2 1234e56 1,2,3.5

1,2,3.+ (1,2.3) $12D45$ -12d-34

and many more variations on these. Would you really consider them acceptable
input?

I haven't tested it (I'll leave that for you to do), but I am pretty sure
using the KeyPress event to "proof" your input will **not** stop a user from
Copy/Pasting non-digits into the TextBox (and I am pretty sure what they
Copy/Paste in will not have to be 7 characters long either).

Rick


> Malik, after playing with the code you gave me....below is the code > that
> works with verifying that it has 7 digits and is a numeric filled > textbox
> and
> the remainder of the code works.. Thanks for your input.....
>
> Linda
>
> Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
> If KeyAscii = vbKeyTab Then
> If TextBox1 = "" Then
> MsgBox "Please enter Accounting Unit Code (7 Digits)"
> Application.SendKeys ("{BS}")
> TextBox1.Activate
> Exit Sub
> End If
> Dim IsValid As Boolean
> IsValid = True
> ' Checking if TextBox value is 7 digits and all the contents are
> numeric
> or not
> IsValid = ((Len(TextBox1.Text) = 7) And IsNumeric(TextBox1.Text))
> If IsValid = False Then
> MsgBox "Accounting Unit Code must contain 7 Digits only" ' , > vbCritical
> + vbOKOnly
> Application.SendKeys ("{BS}")
> Exit Sub
> End If
> KeyAscii = 0
> TextBox3.Activate
> End If
> End Sub
>
> "Malik" wrote:
>
>> Hi,
>>
>> Private Sub TextBox1_LostFocus()
>> Dim IsValid As Boolean
>>
>> IsValid = True
>> ' Checking if TextBox value is 7 digits and all the contents are
>> numeric
>> or not
>> IsValid = ((Len(TextBox1.Text) = 7) And IsNumeric(TextBox1.Text))
>> If IsValid = False Then
>> MsgBox "Please enter 7 numeric digits only...", vbCritical +
>> vbOKOnly
>> End If
>> End Sub
>>
>>
>> You can improve this by adding this routine at any proper place in >> your
>> code
>> -- >> Malik
>>
>>
>> "LRay67" wrote:
>>
>> > I have a required field that can contain only 7 numeric digits >> > within
>> > the
>> > textbox. Also want to put in a message box to alert them that this
>> > field
>> > must have 7 numeric digits. Any suggestions on how to write the >> > code
>> > behind
>> > this? Thanks
>> >
>> > Linda



.

Relevant Pages

  • Re: Help with a Macro
    ... I was only trying to show how you can ensure that a string has two uppercase letters followed six digits. ... Sub test() ... function should exit without running the macro. ...
    (microsoft.public.excel.programming)
  • Re: Required Field for 7 Numeric digits only
    ... Copy/Pasting non-digits into the TextBox. ... Private Sub TextBox1_KeyPress ... MsgBox "Please enter Accounting Unit Code (7 Digits)" ... Dim IsValid As Boolean ...
    (microsoft.public.excel.programming)
  • Re: Required Field for 7 Numeric digits only
    ... Copy/Pasting non-digits into the TextBox (and I am pretty sure what they ... Private Sub TextBox1_KeyPress ... MsgBox "Please enter Accounting Unit Code (7 Digits)" ... Dim IsValid As Boolean ...
    (microsoft.public.excel.programming)
  • Re: How to Force Field Size
    ... will not *store* leading zeros, ... Public Function LeftPadToLength(strVal As String, intLength As Integer, ... I have decided to change my numbers into the 10 digits ... >>End Sub ...
    (microsoft.public.access.modulesdaovba)
  • Project Error
    ... Private Declare Sub Sleep Lib "Kernel32" ... Dim strDataSrc As String ...
    (microsoft.public.vb.bugs)